©2004 Валентин Володин
Сайт Валентина Володина
Главная Статьи Книги и журналы Справочник Программы Ссылки
О себе RytmArc Схемы и описания Резервный форум Разное valvolodin.narod.ru
Калькуляторы Файловый архив Архив форума Форум ГОСТы Измерительные приборы
turbobit mega.co.nz fex.net files.dp.ua ... imageup ... ... ... ...

Power Electronics

Посвящается различным источникам электропитания
Текущее время: 15-10, 17:21

Список форумов » Work category » Конструирование

Часовой пояс: UTC + 4 часа




Начать новую тему Ответить на тему  Страница 162 из 162
  [ Сообщений: 2429 ]  На страницу Пред.  1 ... 158, 159, 160, 161, 162
  Версия для печати Пред. тема | След. тема 
Автор Сообщение
adolw
СообщениеДобавлено: 03-10, 02:57 
Не в сети
Новичок

Зарегистрирован: 02-06, 22:03
Сообщения: 17
Вот ссылка на скриншот моего созданного и работающего символа (символ серого фона), но он без Prefix (в атрибуте все пусто)
https://yapx.ru/album/eQZNc
Если устанавливаю Prefix => X, символ заливается желтым фоном, но не работает (другой скриншот)
https://yapx.ru/album/eQZOi
Пробовал создавать файл .sub в этой же директории, но результат нулевой. Что-то видно делаю не так.
Без Prefix (в атрибуте все пусто), в символе работают любые симисторы и транзисторы, которые есть в моей библиотеке от тов.bordodynovа.
Вернуться к началу
 Профиль  
 
adolw
СообщениеДобавлено: 04-10, 17:06 
Не в сети
Новичок

Зарегистрирован: 02-06, 22:03
Сообщения: 17
Добрый день.
Удалось таки создать, функционирующий свой символ фазового регулятора мощности с желтым фоном. Правда при этом, чуть не пожелтел сам.
Выражаю большую благодарность тов. Володину за подсказку в создание файла .sub

Код:
* C:\Users\Игорь\Documents\LTspiceXVII\lib\sym\ZZZ\Phase_Power_Regulator\GRN-1-220.asc
.SUBCKT GRN-1-220 1 2 3
R1 2 N001 62k
R4 1 N001 1Meg
Q1 N002 N001 N004 0 2N4401
Q2 N006 N001 N004 0 2N4403
Q3 N002 N003 N005 0 2N4401
Q4 N006 N003 N005 0 2N4403
R2 N004 3 27k
C1 2 N004 0.47µ
R3 N005 N003 10k
XU1 1 N005 2 BT134-500
.model NPN NPN
.model PNP PNP
.lib C:\Users\Игорь\Documents\LTspiceXVII\lib\cmp\standard.bjt
.lib TRIAC.lib
.backanno
.ENDS


https://yapx.ru/album/eQwCP

P.S. Просто досталось несметное количество неликвидов ГРН-1-220 на стеклотекстолитовых и алюминиевых подложках времен СССР.
Вернуться к началу
 Профиль  
 
valvol
СообщениеДобавлено: 05-10, 09:52 
Не в сети
Магистр
Аватара пользователя

Зарегистрирован: 06-09, 12:59
Сообщения: 9905
Проблема в том, что ваш библиотечный файл зависит от содержимого других библиотек - standard.bjt и
TRIAC.lib. И это, в общем-то, не есть хорошо.
Но это проблему можно решить, если все необходимые элементы (транзисторы 2N4401, 2N4403 и симистор BT134-500) разместить внутри подсхемы GRN-1-220, как это было показано здесь.
К сожалению, я не смог найти модель BT134-500.
Выложите свой файл TRIAC.lib

_________________
"Древние украли все наши лучшие идеи!"
- Марк Твен.
Вернуться к началу
 Профиль  
 
valvol
СообщениеДобавлено: 05-10, 11:35 
Не в сети
Магистр
Аватара пользователя

Зарегистрирован: 06-09, 12:59
Сообщения: 9905
Для создания модели BT134-500 использовал в качестве прототипа симистор L6004 из библиотеки Teccor.
Получился следующий независимый библиотечный файл GRN-1-220.sub, который необходимо разместить в папке ../lib/sub:
Код:
.SUBCKT GRN-1-220 1 2 3
R1 2 N001 62k
R4 1 N001 1Meg
Q1 N002 N001 N004 0 2N4401
Q2 N006 N001 N004 0 2N4403
Q3 N002 N003 N005 0 2N4401
Q4 N006 N003 N005 0 2N4403
R2 N004 3 27k
C1 2 N004 0.47u
R3 N005 N003 10k
X§U2 1 N005 2 BT134-500 BT134-500 ;§pnba MT2)G)MT1
.model 2N4401 NPN(Is=26.03f Xti=3 Eg=1.11 Vaf=90.7 Bf=4.292K Ne=1.244 Ise=26.03f Ikf=.2061 Xtb=1.5 Br=1.01 Nc=2 Isc=0 Ikr=0 Rc=.5 Cjc=11.01p Mjc=.3763 Vjc=.75 Fc=.5 Cje=24.07p Mje=.3641 Vje=.75 Tr=233.7n Tf=466.5p Itf=0 Vtf=0 Xtf=0 Rb=10)
.model 2N4403 PNP(Is=650.6E-18 Xti=3 Eg=1.11 Vaf=115.7 Bf=216.2 Ne=1.829 Ise=58.72f Ikf=1.079 Xtb=1.5 Br=3.578 Nc=2 Isc=0 Ikr=0 Rc=.715 Cjc=14.76p Mjc=.5383 Vjc=.75 Fc=.5 Cje=19.82p Mje=.3357 Vje=.75 Tr=111.6n Tf=603.7p Itf=.65 Vtf=5 Xtf=1.7 Rb=10)
* BT134-500 SPICE Macromodel
.SUBCKT BT134-500 1  2  3
*     TERMINALS: MT2 G MT1
QN1  5 4 3  NOUT OFF
QN2 11 6 7  NOUT OFF
QP1 6 11 3  POUT OFF
QP2  4 5 7  POUT OFF
DF  4  5  DZ OFF
DR  6 11  DZ OFF
RF  4 6  150MEG
RT2 1 7  0.132
RH  7 6  187
RGP 8 3  136
RG  2 8  65.9
RS  8 4  131
DN  9 2  DIN OFF
RN  9 3  69.5
GNN  6 7 9 3 15.5M
GNP  4 5 9 3 20.5M
DP 2 10  DIP OFF
RP 10 3  40.5
GP  7 6 10 3 10.4M
.MODEL DIN  D (IS=21.4F)
.MODEL DIP  D (IS=21.4F N=1.19)
.MODEL DZ   D (IS=21.4F N=1.5 IBV=4U BV=500)
.MODEL POUT PNP (IS=21.4F BF=5 CJE=625P TF=38.2U)
.MODEL NOUT NPN (IS=21.4F BF=20 CJE=625P CJC=125P TF=2.55U)
.ENDS BT134-500
* End Macromodel
.ends GRN-1-220


Архив с символом, библиотечным файлом и тестовой моделью.

_________________
"Древние украли все наши лучшие идеи!"
- Марк Твен.
Вернуться к началу
 Профиль  
 
adolw
СообщениеДобавлено: 05-10, 12:10 
Не в сети
Новичок

Зарегистрирован: 02-06, 22:03
Сообщения: 17
Разместил Ваш файл sub (../lib/sub) на место своего, в ту же директорию. Все нормально функционирует (как и с моим файлом sub в той же директории)
Вот только при наведение токовых клещей на 2 и 1 выводы GRN-1-220, форма тока не соответствует форме тока через нагрузку (R1), как с моим так и с Вашим файлом sub. И форма токовых клещей разная.
Это так и должно быть???

Ссылка на библиотеку симисторов и BT134-500
https://transfiles.ru/sltpa
Вернуться к началу
 Профиль  
 
valvol
СообщениеДобавлено: 05-10, 19:00 
Не в сети
Магистр
Аватара пользователя

Зарегистрирован: 06-09, 12:59
Сообщения: 9905
adolw писал(а):
Вот только при наведение токовых клещей на 2 и 1 выводы GRN-1-220, форма тока не соответствует форме тока через нагрузку (R1), как с моим так и с Вашим файлом sub. И форма токовых клещей разная.
Это так и должно быть???

В общем-то да. Клещи на выводах GRN-1-220 не имеют стрелки, указывающей направления тока, т.к. всегда показывают втекающий ток. Клещи на резисторе R1 имеют стрелку и показывают ток, текущий в указанном стрелкой направлении. Нажмите F7, затем кликните по резистору R1 левой кнопкой мыши, два раза нажмите комбинацию Ctrl-R и вставьте резистор на место. После этого токи в резисторе R1 и ножке 2 станут абсолютно одинаковыми.

_________________
"Древние украли все наши лучшие идеи!"
- Марк Твен.
Вернуться к началу
 Профиль  
 
adolw
СообщениеДобавлено: 05-10, 20:09 
Не в сети
Новичок

Зарегистрирован: 02-06, 22:03
Сообщения: 17
valvol писал(а):
adolw писал(а):
Нажмите F7, затем кликните по резистору R1 левой кнопкой мыши, два раза нажмите комбинацию Ctrl-R и вставьте резистор на место. После этого токи в резисторе R1 и ножке 2 станут абсолютно одинаковыми.

Резистор R1 перевернулся на 180 градусов. Направление тока на токовых клещах на R1 соответственно изменилось, но на второй ножке форма клещей и тока осталась как и было.
Вернуться к началу
 Профиль  
 
valvol
СообщениеДобавлено: 05-10, 21:18 
Не в сети
Магистр
Аватара пользователя

Зарегистрирован: 06-09, 12:59
Сообщения: 9905
У меня так получается
Изображение

_________________
"Древние украли все наши лучшие идеи!"
- Марк Твен.
Вернуться к началу
 Профиль  
 
adolw
СообщениеДобавлено: 06-10, 09:53 
Не в сети
Новичок

Зарегистрирован: 02-06, 22:03
Сообщения: 17
У меня версия LTspice XVII (17.0.36.0), а у Вас самая последняя.
Может быть из-за этого???
Вернуться к началу
 Профиль  
 
valvol
СообщениеДобавлено: 06-10, 16:56 
Не в сети
Магистр
Аватара пользователя

Зарегистрирован: 06-09, 12:59
Сообщения: 9905
adolw писал(а):
У меня версия LTspice XVII (17.0.36.0), а у Вас самая последняя.
Может быть из-за этого???

Похоже, что так и есть. У меня версия (x64): 26.0.1 всё показывает нормально. А вот LTspice XVII и LTspice IV показывают какую-то ерунду. Надо разобраться. Есть подозрение, что ранние версии LTspice ошибочно показывают токи не во внешних выводах макромодели, в её внутренних цепях, имеющих аналогичное наименование.
Одинаковые имена узлов во внешних и вложенных подсхемах проблем функционирования не вызывают (это базовый движек). А вот внешний алгоритм определения измеряемой цепи путается, если в подсхемах есть имена узлов, схожие с внешними узлами (подключенные к внешним выводам символа).
Пример моделирования модели с символом GRN-1-220 (слева) и с внутренней схемой (справа).
Изображение
Видно, что через вторую ножку символо GRN-1-220, подключенную внутри подсхемы к цепи с именем 2, отображается тот же ток, который течет в управляющем электроде симистора. Модель симистора выполнена в виде вложенной подсхемы, где управляющий электрод также подключен к цепи с именем 2.

_________________
"Древние украли все наши лучшие идеи!"
- Марк Твен.
Вернуться к началу
 Профиль  
 
valvol
СообщениеДобавлено: 06-10, 20:21 
Не в сети
Магистр
Аватара пользователя

Зарегистрирован: 06-09, 12:59
Сообщения: 9905
Похоже прежние версии LTspice (до x64) не понимают вложенные подсхемы.
Обновил файлы в архиве, выложенном чуть раньше. Теперь всё должно работать.
Содержимое обновленного библиотечного файла:
Код:
.SUBCKT GRN-1-220 1 2 3
R1 2 N001 62k
R4 1 N001 1Meg
Q1 N002 N001 N004 0 2N4401
Q2 N006 N001 N004 0 2N4403
Q3 N002 N003 N005 0 2N4401
Q4 N006 N003 N005 0 2N4403
R2 N004 3 27k
C1 2 N004 0.47u
R3 N005 N003 10k
QN1  5 4 2  NOUT OFF
QN2 11 6 7  NOUT OFF
QP1 6 11 2  POUT OFF
QP2  4 5 7  POUT OFF
DF  4  5  DZ OFF
DR  6 11  DZ OFF
RF  4 6  150MEG
RT2 1 7  0.132
RH  7 6  187
RGP 8 2  136
RG  N005 8  65.9
RS  8 4  131
DN  9 N005  DIN OFF
RN  9 2  69.5
GNN  6 7 9 2 15.5M
GNP  4 5 9 2 20.5M
DP N005 10  DIP OFF
RP 10 2  40.5
GP  7 6 10 2 10.4M
.MODEL DIN  D (IS=21.4F)
.MODEL DIP  D (IS=21.4F N=1.19)
.MODEL DZ   D (IS=21.4F N=1.5 IBV=4U BV=500)
.MODEL POUT PNP (IS=21.4F BF=5 CJE=625P TF=38.2U)
.MODEL NOUT NPN (IS=21.4F BF=20 CJE=625P CJC=125P TF=2.55U)
.model 2N4401 NPN(Is=26.03f Xti=3 Eg=1.11 Vaf=90.7 Bf=4.292K Ne=1.244 Ise=26.03f Ikf=.2061 Xtb=1.5 Br=1.01 Nc=2 Isc=0 Ikr=0 Rc=.5 Cjc=11.01p Mjc=.3763 Vjc=.75 Fc=.5 Cje=24.07p Mje=.3641 Vje=.75 Tr=233.7n Tf=466.5p Itf=0 Vtf=0 Xtf=0 Rb=10)
.model 2N4403 PNP(Is=650.6E-18 Xti=3 Eg=1.11 Vaf=115.7 Bf=216.2 Ne=1.829 Ise=58.72f Ikf=1.079 Xtb=1.5 Br=3.578 Nc=2 Isc=0 Ikr=0 Rc=.715 Cjc=14.76p Mjc=.5383 Vjc=.75 Fc=.5 Cje=19.82p Mje=.3357 Vje=.75 Tr=111.6n Tf=603.7p Itf=.65 Vtf=5 Xtf=1.7 Rb=10)
.ends GRN-1-220

_________________
"Древние украли все наши лучшие идеи!"
- Марк Твен.
Вернуться к началу
 Профиль  
 
adolw
СообщениеДобавлено: 06-10, 20:38 
Не в сети
Новичок

Зарегистрирован: 02-06, 22:03
Сообщения: 17
В файле символа GRN-1-220.asy, я изменил:
1=>IN
2=>OUT
3=3
В файле GRN-1-220.sub все соединения заменил соответственно, но все как было так и осталось. Форма тока на выводе OUT GRN-1-220, как на последнем Вашем скриншоте.
Вернуться к началу
 Профиль  
 
valvol
СообщениеДобавлено: 06-10, 20:41 
Не в сети
Магистр
Аватара пользователя

Зарегистрирован: 06-09, 12:59
Сообщения: 9905
adolw писал(а):
В файле символа GRN-1-220.asy, я изменил:

Данная версия устарела. Верните символ в исходное состояние и читайте мое предыдущее сообщение.

_________________
"Древние украли все наши лучшие идеи!"
- Марк Твен.
Вернуться к началу
 Профиль  
 
adolw
СообщениеДобавлено: 06-10, 20:49 
Не в сети
Новичок

Зарегистрирован: 02-06, 22:03
Сообщения: 17
Теперь все нормально.
Еще раз Вас благодарю, за уделенное ко мне время и подробнейшие пояснения в LTspice
Вернуться к началу
 Профиль  
 
Показать сообщения за:  Поле сортировки  
Начать новую тему Ответить на тему  Страница 162 из 162
  [ Сообщений: 2429 ]  На страницу Пред.  1 ... 158, 159, 160, 161, 162

Список форумов » Work category » Конструирование

Часовой пояс: UTC + 4 часа


Кто сейчас на конференции

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 0

Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения

Перейти:  
Powered by Forumenko © 2006–2014
Русская поддержка phpBB
turbobit mega.co.nz fex.net files.dp.ua ... imageup ... ... ... ...
Рейтинг@Mail.ru